/*******************************************************
Program : IoT ESP8266 LOLIN 
1. Relay
2. Sensor Suhu dan Kelembaban DHT11
3. Servo
4. http://bintangterang.or.id/url/6/


Chip       : ESP8266
Website  : https://bintangterang.or.id
Tgl Edite : 16 Maret 2025
Pembuat : OCIM
Pemodal : NIA ASTRIANA
Tempat   : TUK BINTANG TERANG
Penguji   : ASEP

*****************************************/
#include <ESP8266WiFi.h>
#include <WiFiClientSecure.h>  // Untuk HTTPS
#include <ESP8266HTTPClient.h>
#include <ArduinoJson.h>  // For parsing JSON responses
#include <Servo.h>  // For controlling the servo
#include <DHT.h>  // For reading DHT11 sensor

// WiFi credentials
const char* ssid = "BINTANG TERANG";    // Ganti dengan nama WiFi Anda
const char* password = "1sampai8";      // Ganti dengan password WiFi Anda

// URL server PHP
const char* serverUrl = "http://bintangterang.or.id/url/6/device/update_device_status.php"; // URL server
int device_id = 4; // ID perangkat dalam database
int status = 1;  // Initial device status

// Server to get data from
const char* serverName = "https://bintangterang.or.id/url/3/get.php"; // Ganti dengan URL server Anda

// Sertifikat Root CA
const char IRG_Root_X1 [] PROGMEM = R"CERT(
-----BEGIN CERTIFICATE-----
MIIFazCCA1OgAwIBAgIRAIIQz7DSQONZRGPgu2OCiwAwDQYJKoZIhvcNAQELBQAw
TzELMAkGA1UEBhMCVVMxKTAnBgNVBAoTIEludGVybmV0IFNlY3VyaXR5IFJlc2Vh
cmNoIEdyb3VwMRUwEwYDVQQDEwxJU1JHIFJvb3QgWDEwHhcNMTUwNjA0MTEwNDM4
WhcNMzUwNjA0MTEwNDM4WjBPMQswCQYDVQQGEwJVUzEpMCcGA1UEChMgSW50ZXJu
ZXQgU2VjdXJpdHkgUmVzZWFyY2ggR3JvdXAxFTATBgNVBAMTDElTUkcgUm9vdCBY
MTCCAiIwDQYJKoZIhvcNAQEBBQADggIPADCCAgoCggIBAK3oJHP0FDfzm54rVygc
h77ct984kIxuPOZXoHj3dcKi/vVqbvYATyjb3miGbESTtrFj/RQSa78f0uoxmyF+
0TM8ukj13Xnfs7j/EvEhmkvBioZxaUpmZmyPfjxwv60pIgbz5MDmgK7iS4+3mX6U
A5/TR5d8mUgjU+g4rk8Kb4Mu0UlXjIB0ttov0DiNewNwIRt18jA8+o+u3dpjq+sW
T8KOEUt+zwvo/7V3LvSye0rgTBIlDHCNAymg4VMk7BPZ7hm/ELNKjD+Jo2FR3qyH
B5T0Y3HsLuJvW5iB4YlcNHlsdu87kGJ55tukmi8mxdAQ4Q7e2RCOFvu396j3x+UC
B5iPNgiV5+I3lg02dZ77DnKxHZu8A/lJBdiB3QW0KtZB6awBdpUKD9jf1b0SHzUv
KBds0pjBqAlkd25HN7rOrFleaJ1/ctaJxQZBKT5ZPt0m9STJEadao0xAH0ahmbWn
OlFuhjuefXKnEgV4We0+UXgVCwOPjdAvBbI+e0ocS3MFEvzG6uBQE3xDk3SzynTn
jh8BCNAw1FtxNrQHusEwMFxIt4I7mKZ9YIqioymCzLq9gwQbooMDQaHWBfEbwrbw
qHyGO0aoSCqI3Haadr8faqU9GY/rOPNk3sgrDQoo//fb4hVC1CLQJ13hef4Y53CI
rU7m2Ys6xt0nUW7/vGT1M0NPAgMBAAGjQjBAMA4GA1UdDwEB/wQEAwIBBjAPBgNV
HRMBAf8EBTADAQH/MB0GA1UdDgQWBBR5tFnme7bl5AFzgAiIyBpY9umbbjANBgkq
hkiG9w0BAQsFAAOCAgEAVR9YqbyyqFDQDLHYGmkgJykIrGF1XIpu+ILlaS/V9lZL
ubhzEFnTIZd+50xx+7LSYK05qAvqFyFWhfFQDlnrzuBZ6brJFe+GnY+EgPbk6ZGQ
3BebYhtF8GaV0nxvwuo77x/Py9auJ/GpsMiu/X1+mvoiBOv/2X/qkSsisRcOj/KK
NFtY2PwByVS5uCbMiogziUwthDyC3+6WVwW6LLv3xLfHTjuCvjHIInNzktHCgKQ5
ORAzI4JMPJ+GslWYHb4phowim57iaztXOoJwTdwJx4nLCgdNbOhdjsnvzqvHu7Ur
TkXWStAmzOVyyghqpZXjFaH3pO3JLF+l+/+sKAIuvtd7u+Nxe5AW0wdeRlN8NwdC
jNPElpzVmbUq4JUagEiuTDkHzsxHpFKVK7q4+63SM1N95R1NbdWhscdCb+ZAJzVc
oyi3B43njTOQ5yOf+1CceWxG1bQVs5ZufpsMljq4Ui0/1lvh+wjChP4kqKOJ2qxq
4RgqsahDYVvTH9w7jXbyLeiNdd8XM2w9U/t7y0Ff/9yi0GE44Za4rF2LN9d11TPA
mRGunUHBcnWEvgJBQl9nJEiU0Zsnvgc/ubhPgXRR4Xq37Z0j4r7g1SgEEzwxA57d
emyPxgcYxn/eR44/KJ4EBs+lVDR3veyJm+kXQ99b21/+jh5Xos1AnX5iItreGCc=
-----END CERTIFICATE-----
)CERT";

// Relay Pin for controlling relay
const int RELAY_PIN_1 = D1;  // Relay connected to GPIO D1

// Servo setup
Servo myServo;  // Create a servo object
const int SERVO_PIN = D2;  // Servo connected to GPIO D2

// DHT11 sensor setup
#define DHTPIN D3     // Pin where DHT11 is connected
#define DHTTYPE DHT11 // Define the type of DHT sensor
DHT dht(DHTPIN, DHTTYPE);  // Create DHT sensor object

void setup() {
  Serial.begin(115200);

  // Connect to WiFi
  WiFi.begin(ssid, password);
  while (WiFi.status() != WL_CONNECTED) {
    delay(1000);
    Serial.println("Connecting to WiFi...");
  }

  Serial.println("Connected to WiFi");
  Serial.print("IP Address: ");
  Serial.println(WiFi.localIP());

  // Set time via NTP
  configTime(3 * 3600, 0, "pool.ntp.org", "time.nist.gov");

  time_t now = time(nullptr);
  while (now < 8 * 3600 * 2) {
    delay(500);
    now = time(nullptr);
  }

  // Print current time
  struct tm timeinfo;
  gmtime_r(&now, &timeinfo);
  Serial.print("Current time: ");
  Serial.print(asctime(&timeinfo));

  // Initialize relay pin as OUTPUT
  pinMode(RELAY_PIN_1, OUTPUT);
  digitalWrite(RELAY_PIN_1, LOW);  // Turn off relay initially

  // Initialize the servo
  myServo.attach(SERVO_PIN);

  // Initialize DHT sensor
  dht.begin();

  // Get data from server
  getDataFromServer();
}

void loop() {
  // Fetch data from server every 10 seconds
  sendDeviceStatus(status);
  delay(10000);
  getDataFromServer();
}

void getDataFromServer() {
  WiFiClientSecure client;
  HTTPClient http;

  // Set the root certificate for HTTPS
  BearSSL::X509List cert(IRG_Root_X1);
  client.setTrustAnchors(&cert);

  // Start HTTP GET request
  http.begin(client, serverName);
  int httpCode = http.GET();
  Serial.print("HTTP Response code: ");
  Serial.println(httpCode);

  if (httpCode > 0) {
    String payload = http.getString();
    Serial.println("Data received:");
    Serial.println(payload);

    // Parse JSON response
    DynamicJsonDocument doc(1024);
    DeserializationError error = deserializeJson(doc, payload);

    if (error) {
      Serial.println("Error parsing JSON!");
      return;
    }

    // Check if the response is an array and contains at least one object
    if (doc.is<JsonArray>() && doc.size() > 0) {
      for (JsonObject obj : doc.as<JsonArray>()) {
        String id_perintah = obj["id_perintah"];
        String data = obj["data"];

        // Print ID perintah and data
        Serial.print("ID Perintah: ");
        Serial.println(id_perintah);
        Serial.print("Data: ");
        Serial.println(data);

        // Control relay based on id_perintah
        if (id_perintah == "1") {
          controlRelay(RELAY_PIN_1, data);
        }
      }
    } else {
      Serial.println("Invalid or empty JSON response!");
    }
  } else {
    Serial.println("Failed to connect to server");
    Serial.print("HTTP Error: ");
    Serial.println(httpCode);
  }

  http.end();
}

// Function to control relay state based on 'data'
void controlRelay(int relayPin, String state) {
  if (state == "1") {
    Serial.print("Activating Relay on Pin ");
    Serial.println(relayPin);
    digitalWrite(relayPin, HIGH);  // Turn the relay ON
  } else {
    digitalWrite(relayPin, LOW);   // Turn the relay OFF
  }
}

// Function to send device status to server (including temperature and humidity)
void sendDeviceStatus(int status) {
  if (WiFi.status() == WL_CONNECTED) {
    HTTPClient http;
    WiFiClient client;

    // Get DHT11 sensor data
    float temperature = dht.readTemperature();
    float humidity = dht.readHumidity();

    // Check if reading was successful
    if (isnan(temperature) || isnan(humidity)) {
      Serial.println("Failed to read DHT11 sensor!");
      return;
    }

    // Prepare the URL for POST request
    String url = serverUrl;
    http.begin(client, url);
    http.addHeader("Content-Type", "application/x-www-form-urlencoded");

    // Prepare POST data
    String postData = "id_device=" + String(device_id) + "&status=" + String(status) +
                      "&temperature=" + String(temperature) + "&humidity=" + String(humidity);

    // Send POST request
    int httpCode = http.POST(postData);

    if (httpCode > 0) {
      Serial.println("Device status sent successfully!");
      String payload = http.getString();  // Server response
      Serial.println("Server Response: " + payload);
    } else {
      Serial.println("Failed to send device status!");
    }

    http.end();  // Close the connection
  } else {
    Serial.println("WiFi Disconnected");
  }
}